Aladino e le Perle di Saggezza — 21 of 49

Section 5 - Il vecchio saggio

The vecchio saggio is a man in the oasi. "Vedi anche un vecchio [o]saggio[x] che dorme all[']ombra di una palma, con la schiena appoggiata al [o]tronco[x]. E['] molto anziano e le rughe del suo volto trasudano saggezza. Deve conoscere molte cose." The description is "Il vecchio saggio sonnecchia."

Instead of giving something (called the object) to the vecchio saggio:

say "Il vecchio non ha preso [the object]."

The tronco di palma is a scenery in the oasi. The description is "[mostra-palme]A giudicare dal tronco, la palma è vecchia quasi quanto il saggio. Che abbia sempre dormito appoggiato qui?".

The tappeto afghano is a cosa-calpestabile. The keyword is "tappeto". The tappeto afghano is in the oasi. "Il vecchio saggio è seduto su un [o]tappeto[x] afghano originale. Deve essere veramente comodo a giudicare da come ci dorme sopra saporitamente." The description is "[mostra-tappeti]Un tappeto afghano originale[if the player does not wear a paio di sandali]. Salire sul tappeto deve essere un vero sollievo per i piedi[end if]."

Instead of taking a cosa-calpestabile (called the portante) when the cosa-calpestabile supports something (called the portato):

say "Prima di prendere [the portante] devi togliere [the portato]."

After entering the tappeto afghano:

say "[mostra-tappeti]Sali sul [o]tappeto[x] afghano e pensi: 'E['] molto comodo![no line break]'[if the under#tappeto contains something], ma fatto un passo senti che c[']è nascosto sotto qualcosa.[otherwise][line break][end if]"

After touching the tappeto afghano:

say "[mostra-tappeti]Tocchi il [o]tappeto[x] afghano e pensi: 'E['] veramente soffice![no line break]'[if the under#tappeto contains something], ma al tatto senti che c[']è nascosto sotto qualcosa.[otherwise][line break][end if]"

Before doing anything except taking inventory or looking or examining or exiting or getting off or entering when the player is on a cosa-calpestabile (called the tappeto):

say "(prima scendi [dap the tappeto])";

try silently exiting;

continue the action.

Before entering a cosa-calpestabile (called the arrivo) when the player is on a cosa-calpestabile (called the partenza):

if the arrivo is not on the partenza:

say "(prima scendi [dap the tappeto])";

try silently exiting;

continue the action.

An underside called under#tappeto is part of the tappeto afghano. The bulk capacity of the under#tappeto is 5.

The paio di sandali is a wearable thing. The paio di sandali is in the under#tappeto. The description is "Un comodo paio di sandali." The printed name is "paio di [o]sandali[x]".

After looking under the tappeto afghano for the first time:

award 15;

continue the action.

Instead of going somewhere when the player does not wear the paio di sandali and the oasi is visited:

say "Prima di camminare, pensi: 'E['] stupido ferirsi ancora i piedi quando potrei appoggiarli su qualcosa di soffice[if the player carries the paio di sandali] o, addirittura, calzarli con questo bel paio di [o]sandali[x] che ho in mano[end if].'"

Understand "calza" as wearing.

Instead of taking the tappeto afghano:

say "Non puoi prenderlo [scopri-afghano]".

Instead of pulling the tappeto afghano:

say "Non puoi tirarlo [scopri-afghano]".

To say scopri-afghano:

say "[mostra-tappeti]perché c[']è il vecchio saggio seduto sopra.[if the under#tappeto contains something]Nel tirarlo, comunque, ti accorgi di un rigonfiamento e pensi: 'Che ci sia sotto qualcosa?'[end if]".

After putting something (called the nascosto) on an underside (called the sottotappeto):

say "[mostra-tappeti]Hai nascosto [the nascosto] sotto [ap the sottotappeto]."

A puzzle is a kind of thing. A puzzle can be risolto or mescolato.

The cubo di Rubik is a puzzle. The keyword is "cubo". The cubo di Rubik is mescolato. The printed name is "[o]cubo[x] di Rubik".

The cubo di Rubik is in the under#tappeto. The description is "Il mitico cubo di Rubik! [if the cubo is mescolato] E['] mescolato e pensi: 'Chissà se sono ancora capace di risolverlo!'[otherwise] E['] già risolto e pensi: 'Chissà se sarei ancora capace di risolverlo, dopo averlo mescolato.'[end if]".

Mixing is an action applying to one thing.

Solving is an action applying to one thing.

Understand "risolvi [something]" or "risolvi [art-det] [something]" or "risolvi [a known thing]" as solving.

Understand "mescola [something]" or "mescola [art-det] [something]" or "mescola [a known thing]" as mixing.

Check mixing something (called the cubo):

if the cubo is not carried by the player:

say "Non hai in mano [the cubo]." instead;

otherwise if the cubo is not a puzzle:

say "[The cubo] non si può mescolare." instead.

Check solving something (called the cubo):

if the cubo is not carried by the player:

say "Non hai in mano [the cubo]." instead;

otherwise if the cubo is not a puzzle:

say "[The cubo] non si può risolvere." instead.

Carry out mixing something (called the cubo):

if the cubo is mescolato:

say "E['] già mescolato, ma rimescolarlo ancora non fa male.";

otherwise:

say "Mescoli [the cubo] con cura.";

now the cubo is mescolato.

Carry out solving something (called the cubo):

if the cubo is mescolato:

now the cubo is risolto;

say "In meno di dieci secondi risolvi [the cubo]. Nell[']ammirarlo pensi: '[one of]E['] come cavalcare un cammello: certe cose non si dimenticano[or]Nonostante siano passati anni, sono sempre in gamba[at random].'";

otherwise:

say "E['] già risolto!".