Aladino e le Perle di Saggezza — 18 of 49

Section 2 - Il cammello

The gobba is a female supporter. It is part of the cammello. The description is "[mostra-dario-seduto]E['] proprio vero: i dromedari hanno una sola gobba!"

Understand "gobbe" as gobba.

To say mostra-dario-seduto:

[$% show-side figure of dario-seduto; %$]

[$% play sound of cammello; %$]

do nothing.

To say mostra-dario-in-piedi:

[$% show-side figure of dario-in-piedi; %$]

[$% play sound of cammello; %$]

do nothing.

To say Nome-cammello:

say "[if targhetta is unexamined]Il [o]cammello[x][otherwise]Dario il [o]dromedario[x][end if]".

To say nome-cammello:

say "[if targhetta is unexamined]il [o]cammello[x][otherwise]Dario il [o]dromedario[x][end if]".

The cammello is a rideable animal. It is in the serraglio. "[if the targhetta is unexamined]C[']è un [o]cammello[x] molto vecchio, probabilmente abbandonato[otherwise]Vedi [nome-cammello][end if]. Sembra molto stanco, ma potrebbe avere la forza di fare ancora qualche passo.[if the targhetta is unexamined] Che strano! Porta una [o]targhetta[x].[end if]". The description of the cammello is "[mostra-dario-in-piedi][Nome-cammello] non è per niente in forma[if the cammello is affamato] ed è affamato[end if][if the number of things on the gobba is not zero]. Porta [list of things on the gobba with indefinite articles] sulla gobba[end if].[if the targhetta is unexamined] Ha una [o]targhetta[x].[end if]". The printed name is "[if targhetta is unexamined]cammello[otherwise]Dario[end if]".

The targhetta is a female thing part of the cammello. The description is "La targhetta dice:[line break]'[italic type]Questo non è un cammello, è un dromedario![line break]I cammelli hanno due gobbe! Il suo nome è Dario.[line break]Abbine cura e ti porterà molto lontano.[roman type]'[paragraph break]'Che pignoleria!', pensi scocciato, 'Queste stupide bestie con una gobba le ho sempre chiamate cammelli e non comincerò proprio adesso a chiamarle dromedari!'".

After examining the targhetta for the first time:

now the cammello is proper-named;

award 5;

continue the action.

Understand "dario" or "dromedario" as cammello.

A rideable animal can be affamato or sazio. A rideable animal is usually affamato.

Instead of mounting a cammello when the cammello is affamato:

say "[mostra-dario-seduto][Nome-cammello] non ci pensa minimamente a farti salire e ti allontana scalciando e grugnendo. Sembra affamato e dovresti provare a fartelo amico in qualche modo."

Instead of putting something (called the carico) on the cammello:

try putting the carico on the gobba.

Instead of mounting a cammello when the cammello is sazio and the sella per dromedari is not on the gobba:

say "[mostra-dario-seduto][Nome-cammello] non ci pensa proprio a farti cavalcare a pelo, vista la tua tenuta [if the player is not nudo]semi-[end if]adamitica. Dovresti trovare una sella.";

now the sella per cammelli is in the serraglio.

Instead of mounting a cammello when the cammello is sazio and the sella per dromedari is on the gobba and the player carries something:

say "[mostra-dario-in-piedi]Non riesci a salire perché hai le mani impegnate da [the list of things carried by the player with indefinite articles]. Per reggere le redini [if targhetta is unexamined]del [o]cammello[x][otherwise]di Dario il [o]dromedario[x][end if] devi avere le mani libere."

The sella per cammelli is a female cosa-ingombrante. The keyword is "sella". "Vedi una bellissima [o]sella per cammelli[x], tutta istoriata, appoggiata sul suo supporto." The description is "La sella è molto bella e sembra anche comoda."

Instead of putting the sella per cammelli on the cammello:

now the sella per dromedari is in the serraglio;

say mostra-dario-in-piedi;

if the targhetta is unexamined:

say "Il cammello rifiuta la sella e scarta furiosamente. Pensi tra te e te: 'Perché deve essere così difficile? Se solo ci fossero le istruzioni!'";

otherwise:

say "Dario il dromedario si impenna e rifiuta la sella. Ti chiedi nel profondo: 'Per quale ragione esistenziale questo maledetto dromedario non accetta una [o]sella per cammelli[x]?'"

The sella per dromedari is a female cosa-ingombrante. The keyword is "sella". "C[']è anche una [o]sella per dromedari[x] usata in un angolo, così vecchia e consumata che ad una prima occhiata ti era sfuggita." The description is "La sella è vecchia, ma soprattutto scomoda."

After putting the sella per dromedari on the gobba for the first time:

award 50;

continue the action.

Instead of kissing a rideable animal:

say "Ora le ho proprio viste tutte!".

Instead of kissing a rideable animal for the second time:

say "Ci hai proprio preso gusto!".

Instead of kissing a rideable animal for the third time:

say "Non posso più guardare!".

Instead of kissing a rideable animal for more than the third time:

say "Non sto guardando, mi sto coprendo gli occhi!".

Instead of giving the dattero to the cammello:

now the cammello is not affamato;

award 10;

remove the dattero from play;

say "[mostra-dario-in-piedi]Il cammello afferra avidamente il dattero con la lunga lingua e grugnisce riconoscente."

The check-not-animal rule is listed instead of the can't take people's possessions rule in the check taking rules.

Check an actor taking (this is the check-not-animal rule):

let the local ceiling be the common ancestor of the actor with the noun;

let H be the not-counting-parts holder of the noun;

while H is not nothing and H is not the local ceiling:

if H is a person and H is not an animal, stop the action with library message taking action number 6 for H;

let H be the not-counting-parts holder of H;

After going somewhere by a rideable animal (called the mounted):

say mostra-uomo-e-dario-1;

if the asino is tied:

if the forziere is on the dorso:

say mostra-uomo-e-dario-2;

move the asino to room gone to;

otherwise:

now the asino is untied;

now the fune is in the room gone from;

say "[mostra-asino]L[']asino con uno strattone si libera dalla fune e non ti segue. Probabilmente la soma che ha sul dorso non è abbastanza pesante per i suoi gusti.";

say "[The mounted] trotta nella direzione [dip the room gone to][if the asino is tied] e l[']asino lo segue diligentemente[end if].";

continue the action.

After going somewhere when the player is not carried by a rideable animal:

say mostra-uomo-e-orme;

continue the action.

Instead of going to a luogo-lontano when the player is not carried by a rideable animal:

[$% show-top the top-illustration of the room gone to; %$]

say mostra-uomo-e-orme;

say "[The room gone to] è troppo distante. Moriresti di sete. Devi usare una cavalcatura."

Instead of going from a luogo-lontano when the player is not carried by a rideable animal:

if (a rideable animal is in the location) or (the room gone to is the deserto di sabbia):

[$%

show-top the top-illustration of the room gone to;

%$]

say mostra-uomo-e-orme;

say "[The room gone to] è troppo distante. Moriresti di sete. Non devi abbandonare la cavalcatura.";

otherwise:

continue the action.

Instead of going to a luogo-molto-lontano when the player is not carried by the cammello or the otri pieni are not on the gobba:

[$% show-top the top-illustration of the room gone to; %$]

say mostra-uomo-e-orme;

say "[The room gone to] è troppo caldo. Devi portare molta acqua con te [if the player is carried by a rideable animal (called the mounted)]altrimenti tu e [the mounted] morirete[otherwise]e trovare una cavalcatura altrimenti morirai[end if] di sete."

Instead of going from a luogo-molto-lontano when the player is not carried by the cammello or the otri pieni are not on the gobba:

[$% show-top the top-illustration of the room gone to; %$]

say mostra-uomo-e-dario-1;

say "[The room gone to] è veramente troppo lontano. Devi portare molta acqua con te [if the player is carried by a rideable animal (called the mounted)]altrimenti tu e [the mounted] morirete[otherwise]e non devi abbandonare la cavalcatura altrimenti morirai[end if] di sete."